日付・時刻の取得や一定時間待ち合わせする

日付を取得する

現在の年・月・日を取得します。
年を２桁でもらう方法と４桁でもらう方法の２種類があります。
実際にもらえる日付はサーバのシステム日付です。（サーバのコントロールパネルにある「日付と時刻」などで日付を変更すれば、ここで貰える日付も変わる。）

◆年月日（年は２桁）を取得できるACCEPT（小入力）命令

Ａ−ＶＸ　ＣＯＢＯＬ８５では昔から使える標準的な命令です。

ＮＥＣ正式版の説明書「ＣＯＢＯＬ８５言語説明書」−「第３章　中核」−「３．６．５　ＡＣＣＥＰＴ命令」に書いてあります。
その説明書から概要を下に抜き出します。

一般形式 ACCEPT 一意名 FROM DATE

一意名は６桁の符号なし数字項目と定義されているものとする。
年の下２桁、月、日の順番に構成される。例えば2012年2月14日は120214となる。

現在の年月日を６桁でシステムからもらいます。年は２桁。
ＡＣＣＥＰＴでもらえる年が西暦年と和暦年のどちらかは、システム生成で決められています。どちらになっているかはシステム生成の情報を印刷・表示するユーティリティ：＃ＳＧＬＳＴで調べることができます。

◆年月日（年は４桁）を取得できるシステムサブルーチン

かつて２０００年問題が話題になっていた頃に新規に用意されたシステムサブルーチンです。なので、その頃より昔のシステムでは使用できません。

ＮＥＣ正式版の説明書「ＣＯＢＯＬ８５システムサブルーチン説明書」−「第６章　システムインタフェースサブルーチン」−「６．１３　西暦２０００年対応　日付の取得」に書いてあります。
その説明書から概要を下に抜き出します。

一般形式 CALL "CBLDATE" USING データ名

データ名：西暦日付
データ名は8桁の符号なし数字項目。日付をyyyymmdd形式で格納します。
yyyyは西暦年４桁を表し、mmは月を数字２桁で表わし、ddはその日を表します。
システム生成の状態が和暦の場合、西暦年の値は保証しません。

現在の年月日を８桁でシステムからもらいます。年は４桁。西暦のシステムであることが使用する条件のようです。
システムが西暦のシステムなのか和暦のシステムなのか、どちらになっているかはシステム生成の情報を印刷・表示するユーティリティ：＃ＳＧＬＳＴで調べることができます。

もしリンクでエラーになるようであれば、このシステムサブルーチンシステムに登録されていない可能性があるので、「システム導入・変更の手引き」の「付録　「西暦２０００年対応　日付の取得」ＣＯＢＯＬシステムサブルーチンのＳＵとＣＵの登録方法」を見て登録します。
ＣＢＬＤＡＴＥＳという名前のソースプログラムもあるみたいです。（サンプルプログラム？）

◆年（２桁）と通日（１月１日からの日数）を取得できるACCEPT（小入力）命令

ＮＥＣ正式版の説明書「ＣＯＢＯＬ８５言語説明書」−「第３章　中核」−「３．６．５　ＡＣＣＥＰＴ命令」に書いてあります。
その説明書から概要を下に抜き出します。

一般形式 ACCEPT 一意名 FROM DAY

一意名は６けたの符号なし数字項目として定義されているものとする。
例えば1985年2月14日は85045となる。

現在の年と通日（１月１日からの日数）をシステムからもらうことができます。
年の部分は「年月日（年は２桁）を取得できるACCEPT（小入力）命令」でもらえるものと同じです。

◆曜日を取得できるACCEPT（小入力）命令

ＮＥＣ正式版の説明書「ＣＯＢＯＬ８５言語説明書」−「第３章　中核」−「３．６．５　ＡＣＣＥＰＴ命令」に書いてあります。
その説明書から概要を下に抜き出します。

一般形式 ACCEPT 一意名 FROM DAY-OF-WEEK

一意名は１桁の符号なし数字項目として定義されているものとする。
一意名に入る値は、１は月曜日を示し、２は火曜日を示し、・・・７は日曜日を示す。

曜日	月	火	水	木	金	土	日
値	1	2	3	4	5	6	7

現在の曜日を対応する数字１桁でシステムからもらいます。

時刻を取得する

ＮＥＣ正式版の説明書「ＣＯＢＯＬ８５言語説明書」−「第３章　中核」−「３．６．５　ＡＣＣＥＰＴ命令」に書いてあります。
その説明書から概要を下に抜き出します。

一般形式 ACCEPT 一意名 FROM TIME

一意名は８桁の符号なし数字項目として定義されているものとする。
時（２桁）、分（２桁）、秒（２桁）、１００分の１秒（２桁）の順番で構成される。午前零時を起点とする２４時間表示とする。このうち、１００分の１秒は常に００である。
例えば午後２時４１分３２秒は、14413200となる。

現在の時刻（時分秒）をシステムからもらうことができます。
実際にもらえる時刻はサーバのシステム時刻です。（サーバのコントロールパネルにある「日付と時刻」などで時刻を変更すれば、ここでもらえる時刻も変わる。）

一定時間待ち合わせする

ＮＥＣ正式版の説明書「ＣＯＢＯＬ８５システムサブルーチン説明書」−「第６章　システムインタフェースサブルーチン」−「６．２　インターバルタイマ」に書いてあります。
その説明書から概要を下に抜き出します。

一般形式 CALL "CBLTIMER" USING データ名

データ名：待ち時間
データ名はレベル番号０１または７７の４桁の符号なし数字項目。
ＣＡＬＬ命令を実行すると、プログラムは一定の時間待ちの状態になります。
データ名の値によって待ち時間が決定されます。１／１０秒単位で、最高３２０秒までの時間が設定できます。
例　０．５・・・０００５ 　　１秒　・・・００１０ 　　１分　・・・０６００ 　０あるいは３２０１以上の値を指定した場合は、何も実行せずに、ＣＡＬＬ命令の次の命令に実行が移ります。

サンプルプログラム

Ａ−ＶＸのＣＯＢＯＬ８５で標準で用意されている日付や時刻に関する命令やシステムサブルーチンを使ったサンプルプログラムを紹介します。

サンプルプログラム１

サンプルプログラム１で使用しているものは次の５種類です。

• 現在年月日（年は２桁）を取得できるACCEPT（小入力）命令
• 現在年月日（年は４桁）を取得できるシステムサブルーチン
• 現在時刻を取得できるACCEPT（小入力）命令
• 年（２桁）と通日（１月１日からの日数）を取得できるACCEPT（小入力）命令
• 曜日を取得できるACCEPT（小入力）命令

000010************************************************************ 000020** 日付・時刻取得　　　　　　　　　　　　　　　　　　　 ** 000030** サンプルプログラム１ ** 000040************************************************************ 000050 IDENTIFICATION DIVISION. 000060 PROGRAM-ID. SAM001. 000070* 000080 ENVIRONMENT DIVISION. 000090* 000100 DATA DIVISION. 000110 WORKING-STORAGE SECTION. 000120*--------時刻取得の為のデータ項目--------------------------- 000130 01 GETTIME PIC 9(08). 000140 01 GETTIME-R REDEFINES GETTIME. 000150 05 GTIM PIC 9(02). 000160 05 GMIN PIC 9(02). 000170 05 GSEC PIC 9(02). 000180 05 GMIL PIC 9(02). 000190*--------日付取得の為のデータ項目--------------------------- 000200 01 2NEN PIC 9(06). 000210 01 2NEN-R REDEFINES 2NEN. 000220 05 YEAR-2 PIC 9(02). 000230 05 MONTH-2 PIC 9(02). 000240 05 DATE-2 PIC 9(02). 000250*--------４桁年（西暦２０００年対応日付の取得）のデータ項目- 000260 01 4NEN PIC 9(08). 000270 01 4NEN-R REDEFINES 4NEN. 000280 05 YEAR-4 PIC 9(04). 000290 05 MONTH-4 PIC 9(02). 000300 05 DATE-4 PIC 9(02). 000310*-------１月１日からの日数（通日）の為のデータ項目--------- 000320 01 GETDAY PIC 9(05). 000330 01 GETDAY-R REDEFINES GETDAY. 000340 05 GYEAR PIC 9(02). 000350 05 GDAY PIC 9(03). 000360*-------曜日の為のデータ項目------------------------------- 000370 01 DAYOFW PIC 9(01). 000380 01 GR-YOUBI. 000390 05 YY PIC N(07) VALUE NC"月火水木金土日". 000400 05 YOUBI REDEFINES YY PIC X(02) OCCURS 7. 000410*-------キー待ち合わせ用データ項目------------------------- 000420 01 KEYIN PIC X(01). 000430* 000440 PROCEDURE DIVISION. 000450 MPRG. 000460 INITIALIZE GETTIME 2NEN 4NEN GETDAY DAYOFW. 000470*-------現在日付の取得------------------------------------- 000480 ACCEPT 2NEN FROM DATE. 000490*-------４桁年の日付の取得--------------------------------- 000500 CALL "CBLDATE" USING 4NEN. 000510*-------現在時刻の取得------------------------------------- 000520 ACCEPT GETTIME FROM TIME. 000530*-------通日の取得----------------------------------------- 000540 ACCEPT GETDAY FROM DAY. 000550*-------曜日の取得----------------------------------------- 000560 ACCEPT DAYOFW FROM DAY-OF-WEEK. 000570*---------------------------------------------------------- 000580*---------- 画面表示 -------------------------------------- 000590*---------------------------------------------------------- 000600 DISPLAY "現在日付：　" YEAR-2 "年" MONTH-2 "月" DATE-2 "日". 000610 DISPLAY "４桁年　：" YEAR-4 "年" MONTH-4 "月" DATE-4 "日". 000620 DISPLAY "現在時刻：　" GTIM "時" GMIN "分" GSEC "秒" GMIL. 000630 DISPLAY "通日　　：　" GYEAR "年" GDAY "日". 000640 DISPLAY "曜日　　：　" YOUBI(DAYOFW). 000650*--------------------------------------------------------------- 000660 DISPLAY "やめる時はエンターキーを押して". 000670 ACCEPT KEYIN. 000680 STOP RUN.

西暦表示のシステムでサンプルプログラム１を実行した例

サンプルプログラム２

サンプルプログラム２で使用しているものは次の４種類です。

• 現在時刻を取得できるACCEPT（小入力）命令
• 現在年月日（年は２桁）を取得できるACCEPT（小入力）命令
• 現在年月日（年は４桁）を取得できるシステムサブルーチン
• 一定時間待ち合わせを行うシステムサブルーチン

最初に日付（年は２桁）と時刻を画面表示し、５分待ち合わせ、待ち合わせが終わったらもう一度日付（４桁）と時刻を画面表示します。

000010*********************************************************** 000020** インタバルタイマーと日付・時刻取得 ** 000030** サンプルプログラム２ ** 000040*********************************************************** 000050 IDENTIFICATION DIVISION. 000060 PROGRAM-ID. SAM002. 000070* 000080 ENVIRONMENT DIVISION. 000090* 000100 DATA DIVISION. 000110 WORKING-STORAGE SECTION. 000120*--------時刻取得の為のデータ項目-------------------- 000130 01 GETTIME. 000140 05 GTIM PIC 9(02). 000150 05 GMIN PIC 9(02). 000160 05 GSEC PIC 9(02). 000170 05 GMIL PIC 9(02). 000180 01 GETTIME-R REDEFINES GETTIME PIC 9(08). 000190*--------日付の取得のためのデータ項目---------------- 000200 01 2NEN. 000210 05 YEAR-2 PIC 9(02). 000220 05 MONTH-2 PIC 9(02). 000230 05 DATE-2 PIC 9(02). 000240 01 2NEN-R REDEFINES 2NEN PIC 9(06). 000250*--------インターバルタイマーのデータ項目------------ 000260 01 INTTMR. 000270 05 SEC PIC 9(03). 000280 05 FILLER PIC 9(01) VALUE ZERO. 000290 01 INTTMR-R REDEFINES INTTMR PIC 9(04). 000300*--------４桁年（西暦２０００年対応日付の取得）のデータ項目 000310 01 4NEN. 000320 05 YEAR-4 PIC 9(04). 000330 05 MONTH-4 PIC 9(02). 000340 05 DATE-4 PIC 9(02). 000350 01 4NEN-R REDEFINES 4NEN PIC 9(08). 000360*--------キー待ち合わせ用データ項目------------------ 000370 01 KEYIN PIC X(01). 000380* 000390 PROCEDURE DIVISION. 000400 MPRG. 000410 DISPLAY "５分ぐらい待ち合わせます。". 000420*----------------------------------------------------- 000430*--------現在時刻の取得------------------------------- 000440 INITIALIZE GETTIME-R 000450 ACCEPT GETTIME-R FROM TIME. 000460*----------------------------------------------------- 000470*--------現在日付の取得------------------------------- 000480 INITIALIZE 2NEN-R 000490 ACCEPT 2NEN-R FROM DATE. 000500*----------------------------------------------------- 000510*--------開始日時の表示------------------------------- 000520 DISPLAY "開始時刻： " YEAR-2 "." MONTH-2 "." DATE-2 000530 " " GTIM ":" GMIN ":" GSEC. 000540*----------------------------------------------------- 000550*------- インターバルタイマーの処理 ------------------ 000560* 待ち時間をセット（３００秒＝５分） 000570* セットできるのは１〜３２０秒まで 000580 MOVE 300 TO SEC 000590* 待ち合わせ実施 000600 CALL "CBLTIMER" USING INTTMR-R. 000610*----------------------------------------------------- 000620*--------４桁年の日付の取得の処理--------------------- 000630 INITIALIZE 4NEN 000640 CALL "CBLDATE" USING 4NEN-R. 000650*----------------------------------------------------- 000660*--------終わり日時の表示----------------------------- 000670 INITIALIZE GETTIME-R 000680 ACCEPT GETTIME-R FROM TIME. 000690 DISPLAY "終了時刻：" YEAR-4 "." MONTH-4 "." DATE-4 000700 " " GTIM ":" GMIN ":" GSEC. 000710 DISPLAY "待ち合わせ終了。やめる時はエンターキー押して" 000720 ACCEPT KEYIN. 000730 STOP RUN.

西暦表示のシステムでサンプルプログラム２を実行した例


和暦表示のシステムでサンプルプログラム２を実行した例
NECの正式版説明書の注意事項によると和暦表示のシステムの場合は４桁の方は値の保証はしていないとのこと。（今回の例では和暦でもらえている点に注意。）